mirror of
https://github.com/Xahau/xahaud.git
synced 2025-11-04 10:45:50 +00:00
c3a9f3dbf3
Introduces a conanfile.py (and a Conan recipe for RocksDB) to enable building the package with Conan, choosing more recent default versions of dependencies. It removes almost all of the CMake build files related to dependencies, and the configurations for Travis CI and GitLab CI. A new set of cross-platform build instructions are written in BUILD.md. Includes example GitHub Actions workflow for each of Linux, macOS, Windows. * Test on macos-12 We use the <concepts> library which was not added to Apple Clang until version 13.1.6. The default Clang on macos-11 (the sometimes current version of macos-latest) is 13.0.0, and the default Clang on macos-12 is 14.0.0. Closes #4223.
40 lines
1.4 KiB
CMake
40 lines
1.4 KiB
CMake
#[===================================================================[
|
|
multiconfig misc
|
|
#]===================================================================]
|
|
|
|
if (is_multiconfig)
|
|
# This code finds all source files in the src subdirectory for inclusion
|
|
# in the IDE file tree as non-compiled sources. Since this file list will
|
|
# have some overlap with files we have already added to our targets to
|
|
# be compiled, we explicitly remove any of these target source files from
|
|
# this list.
|
|
file (GLOB_RECURSE all_sources RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
|
|
CONFIGURE_DEPENDS
|
|
src/*.* Builds/*.md docs/*.md src/*.md Builds/*.cmake)
|
|
file(GLOB md_files RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} CONFIGURE_DEPENDS
|
|
*.md)
|
|
LIST(APPEND all_sources ${md_files})
|
|
foreach (_target secp256k1::secp256k1 ed25519::ed25519 pbufs xrpl_core rippled)
|
|
get_target_property (_type ${_target} TYPE)
|
|
if(_type STREQUAL "INTERFACE_LIBRARY")
|
|
continue()
|
|
endif()
|
|
get_target_property (_src ${_target} SOURCES)
|
|
list (REMOVE_ITEM all_sources ${_src})
|
|
endforeach ()
|
|
target_sources (rippled PRIVATE ${all_sources})
|
|
set_property (
|
|
SOURCE ${all_sources}
|
|
APPEND
|
|
PROPERTY HEADER_FILE_ONLY true)
|
|
if (MSVC)
|
|
set_property(
|
|
DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
PROPERTY VS_STARTUP_PROJECT rippled)
|
|
endif ()
|
|
|
|
group_sources(src)
|
|
group_sources(docs)
|
|
group_sources(Builds)
|
|
endif ()
|