Fix Doxygen build

Builds/CMake/RippledDocs.cmake

@@ -3,29 +3,82 @@
 #]===================================================================]
 
 find_package (Doxygen)
-if (TARGET Doxygen::doxygen)
-  set (doc_srcs docs/source.dox)
-  file (GLOB_RECURSE other_docs docs/*.md)
-  list (APPEND doc_srcs "${other_docs}")
-  # read the source config and make a modified one
-  # that points the output files to our build directory
-  file (READ "${CMAKE_CURRENT_SOURCE_DIR}/docs/source.dox" dox_content)
-  string (REGEX REPLACE "[\t ]*OUTPUT_DIRECTORY[\t ]*=(.*)"
-    "OUTPUT_DIRECTORY=${CMAKE_BINARY_DIR}\n\\1"
-    new_config "${dox_content}")
-  file (WRITE "${CMAKE_BINARY_DIR}/source.dox" "${new_config}")
-  add_custom_target (docs
-    COMMAND "${DOXYGEN_EXECUTABLE}" "${CMAKE_BINARY_DIR}/source.dox"
-    BYPRODUCTS "${CMAKE_BINARY_DIR}/html_doc/index.html"
-    WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/docs"
-    SOURCES "${doc_srcs}")
-  if (is_multiconfig)
-    set_property (
-      SOURCE ${doc_srcs}
-      APPEND
-      PROPERTY HEADER_FILE_ONLY
-      true)
-  endif ()
-else ()
+if (NOT TARGET Doxygen::doxygen)
   message (STATUS "doxygen executable not found -- skipping docs target")
+  return ()
+endif ()
+
+set (doxygen_output_directory "${CMAKE_BINARY_DIR}/docs")
+set (doxygen_include_path "${CMAKE_SOURCE_DIR}/src")
+set (doxygen_index_file "${doxygen_output_directory}/html/index.html")
+set (doxyfile "${CMAKE_CURRENT_SOURCE_DIR}/docs/Doxyfile")
+
+file (GLOB_RECURSE doxygen_input
+  docs/*.md
+  src/ripple/*.h
+  src/ripple/*.cpp
+  src/ripple/*.md
+  src/test/*.h
+  src/test/*.md
+  Builds/*/README.md)
+list (APPEND doxygen_input
+  README.md
+  RELEASENOTES.md
+  src/README.md)
+set (dependencies "${doxygen_input}" "${doxyfile}")
+
+function (verbose_find_path variable name)
+  # find_path sets a CACHE variable, so don't try using a "local" variable.
+  find_path (${variable} "${name}" ${ARGN})
+  if (NOT ${variable})
+    message (WARNING "could not find ${name}")
+  else ()
+    message (STATUS "found ${name}: ${${variable}}/${name}")
+  endif ()
+endfunction ()
+
+verbose_find_path (doxygen_plantuml_jar_path plantuml.jar PATH_SUFFIXES share/plantuml)
+verbose_find_path (doxygen_dot_path dot)
+
+# https://en.cppreference.com/w/Cppreference:Archives
+# https://stackoverflow.com/questions/60822559/how-to-move-a-file-download-from-configure-step-to-build-step
+set (download_script "${CMAKE_BINARY_DIR}/docs/download-cppreference.cmake")
+file (WRITE
+  "${download_script}"
+  "file (DOWNLOAD \
+    http://upload.cppreference.com/mwiki/images/b/b2/html_book_20190607.zip \
+    ${CMAKE_BINARY_DIR}/docs/cppreference.zip \
+    EXPECTED_HASH MD5=82b3a612d7d35a83e3cb1195a63689ab \
+  )\n \
+  execute_process ( \
+    COMMAND \"${CMAKE_COMMAND}\" -E tar -xf cppreference.zip \
+  )\n"
+)
+set (tagfile "${CMAKE_BINARY_DIR}/docs/cppreference-doxygen-web.tag.xml")
+add_custom_command (
+  OUTPUT "${tagfile}"
+  COMMAND "${CMAKE_COMMAND}" -P "${download_script}"
+  WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/docs"
+)
+set (doxygen_tagfiles "${tagfile}=http://en.cppreference.com/w/")
+
+add_custom_command (
+  OUTPUT "${doxygen_index_file}"
+  COMMAND "${CMAKE_COMMAND}" -E env
+    "DOXYGEN_OUTPUT_DIRECTORY=${doxygen_output_directory}"
+    "DOXYGEN_INCLUDE_PATH=${doxygen_include_path}"
+    "DOXYGEN_TAGFILES=${doxygen_tagfiles}"
+    "DOXYGEN_PLANTUML_JAR_PATH=${doxygen_plantuml_jar_path}"
+    "DOXYGEN_DOT_PATH=${doxygen_dot_path}"
+    "${DOXYGEN_EXECUTABLE}" "${doxyfile}"
+  WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
+  DEPENDS "${dependencies}" "${tagfile}")
+add_custom_target (docs
+  DEPENDS "${doxygen_index_file}"
+  SOURCES "${dependencies}")
+if (is_multiconfig)
+  set_property (
+    SOURCE ${dependencies}
+    APPEND PROPERTY
+    HEADER_FILE_ONLY true)
 endif ()