mirror of
https://github.com/XRPLF/rippled.git
synced 2025-11-07 12:45:51 +00:00
ea1fffeebf
Adds two CMake functions:
* add_module(library subdirectory): Declares an OBJECT "library" (a CMake abstraction for a collection of object files) with sources from the given subdirectory of the given library, representing a module. Isolates the module's headers by creating a subdirectory in the build directory, e.g. .build/tmp123, that contains just a symlink, e.g. .build/tmp123/basics, to the module's header directory, e.g. include/xrpl/basics, in the source directory, and putting .build/tmp123 (but not include/xrpl) on the include path of the module sources. This prevents the module sources from including headers not explicitly linked to the module in CMake with target_link_libraries.
* target_link_modules(library scope modules...): Links the library target to each of the module targets, and removes their sources from its source list (so they are not compiled and linked twice).
Uses these functions to separate and explicitly link modules in libxrpl:
Level 01: beast
Level 02: basics
Level 03: json, crypto
Level 04: protocol
Level 05: resource, server
38 lines
1.1 KiB
CMake
38 lines
1.1 KiB
CMake
include(isolate_headers)
|
|
|
|
# Create an OBJECT library target named
|
|
#
|
|
# ${PROJECT_NAME}.lib${parent}.${name}
|
|
#
|
|
# with sources in src/lib${parent}/${name}
|
|
# and headers in include/${parent}/${name}
|
|
# that cannot include headers from other directories in include/
|
|
# unless they come through linked libraries.
|
|
#
|
|
# add_module(parent a)
|
|
# add_module(parent b)
|
|
# target_link_libraries(project.libparent.b PUBLIC project.libparent.a)
|
|
function(add_module parent name)
|
|
set(target ${PROJECT_NAME}.lib${parent}.${name})
|
|
add_library(${target} OBJECT)
|
|
file(GLOB_RECURSE sources CONFIGURE_DEPENDS
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/src/lib${parent}/${name}/*.cpp"
|
|
)
|
|
target_sources(${target} PRIVATE ${sources})
|
|
target_include_directories(${target} PUBLIC
|
|
"$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
|
|
)
|
|
isolate_headers(
|
|
${target}
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/include"
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/include/${parent}/${name}"
|
|
PUBLIC
|
|
)
|
|
isolate_headers(
|
|
${target}
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/src"
|
|
"${CMAKE_CURRENT_SOURCE_DIR}/src/lib${parent}/${name}"
|
|
PRIVATE
|
|
)
|
|
endfunction()
|