mirror of
https://github.com/XRPLF/rippled.git
synced 2026-08-21 22:30:57 +00:00
3860c93db2
These changes were developed on the phase-10 branch but belong to content this branch and its upstreams introduced. Carrying them on phase-10 made its PR diff report churn in files phase-10 does not own, and left each PR claiming a scope that did not match its contents. Moved here from phase-10 (identical content, no functional change): - Dashboards: all 14 existing boards plus the new log-derived-insights board. - Docs: telemetry-runbook.md (minus the workload/benchmark sections, which describe phase-10 tooling) and the new telemetry-glossary.md. - Grafana Cloud + Alloy export path: collector config, compose override, the two .env examples and alloy/config.alloy. - Local stack: otel-collector-config.yaml gains sub-millisecond and second-scale spanmetrics buckets, pins unit=ms, and promotes close_time_correct; integration-test.sh and TESTING.md follow. - Node configs: exported_instance -> service_instance_id in comments; the mainnet sample now logs at warning to bound log volume. - Metrics code: Telemetry.cpp builds the metrics pipeline in the constructor via initMetrics() so the global MeterProvider is published before any subsystem creates a beast::insight instrument, and the histogram view keeps each instrument's own name instead of collapsing them under one series. MetricsRegistry gains a last_close_time gauge and skips negative job-queue durations. OTelCollector drops an unused accessor. - Naming CI: xrpl_work_item joins EXTERNAL_INFRA_LABELS and Rule E accepts the dotted perf-iac resource-attribute form. This must travel with the dashboards and runbook that reference those labels, or the rules fail. - Doxygen input glob no longer recurses dot-directories. Sections describing phase-10 tooling stay on phase-10 and keep their "Future Enhancement" / "Planned, not yet implemented" markers here; phase-10 removes those markers when it lands the tooling.
96 lines
3.0 KiB
CMake
96 lines
3.0 KiB
CMake
#[===================================================================[
|
|
docs target (optional)
|
|
#]===================================================================]
|
|
|
|
if(NOT only_docs)
|
|
return()
|
|
endif()
|
|
|
|
find_package(Doxygen)
|
|
if(NOT TARGET Doxygen::doxygen)
|
|
message(STATUS "doxygen executable not found -- skipping docs target")
|
|
return()
|
|
endif()
|
|
|
|
set(doxygen_output_directory "${CMAKE_BINARY_DIR}/docs")
|
|
set(doxygen_include_path "${CMAKE_CURRENT_SOURCE_DIR}/src")
|
|
set(doxygen_index_file "${doxygen_output_directory}/html/index.html")
|
|
set(doxyfile "${CMAKE_CURRENT_SOURCE_DIR}/docs/Doxyfile")
|
|
|
|
file(
|
|
GLOB_RECURSE doxygen_input
|
|
docs/*.md
|
|
include/*.h
|
|
include/*.cpp
|
|
include/*.md
|
|
src/*.h
|
|
src/*.cpp
|
|
src/*.md
|
|
Builds/*.md
|
|
)
|
|
# Add only top-level .md files (README, CONTRIBUTING, etc.) without
|
|
# recursing into dot-directories like .claude/ whose files are not
|
|
# valid Doxygen/CMake sources.
|
|
file(GLOB doxygen_top_md CONFIGURE_DEPENDS "*.md")
|
|
list(APPEND doxygen_input ${doxygen_top_md})
|
|
list(APPEND doxygen_input external/README.md)
|
|
set(dependencies "${doxygen_input}" "${doxyfile}")
|
|
|
|
function(verbose_find_path variable name)
|
|
# find_path sets a CACHE variable, so don't try using a "local" variable.
|
|
find_path(${variable} "${name}" ${ARGN})
|
|
if(NOT ${variable})
|
|
message(NOTICE "could not find ${name}")
|
|
else()
|
|
message(STATUS "found ${name}: ${${variable}}/${name}")
|
|
endif()
|
|
endfunction()
|
|
|
|
verbose_find_path(
|
|
doxygen_plantuml_jar_path
|
|
plantuml.jar
|
|
PATH_SUFFIXES share/plantuml
|
|
)
|
|
verbose_find_path(doxygen_dot_path dot)
|
|
|
|
# https://en.cppreference.com/w/Cppreference:Archives
|
|
# https://stackoverflow.com/questions/60822559/how-to-move-a-file-download-from-configure-step-to-build-step
|
|
set(download_script "${CMAKE_BINARY_DIR}/docs/download-cppreference.cmake")
|
|
file(
|
|
WRITE "${download_script}"
|
|
"file(DOWNLOAD \
|
|
https://github.com/PeterFeicht/cppreference-doc/releases/download/v20250209/html-book-20250209.zip \
|
|
${CMAKE_BINARY_DIR}/docs/cppreference.zip \
|
|
EXPECTED_HASH MD5=bda585f72fbca4b817b29a3d5746567b \
|
|
)\n \
|
|
execute_process( \
|
|
COMMAND \"${CMAKE_COMMAND}\" -E tar -xf cppreference.zip \
|
|
)\n"
|
|
)
|
|
set(tagfile "${CMAKE_BINARY_DIR}/docs/cppreference-doxygen-web.tag.xml")
|
|
add_custom_command(
|
|
OUTPUT "${tagfile}"
|
|
COMMAND "${CMAKE_COMMAND}" -P "${download_script}"
|
|
WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/docs"
|
|
)
|
|
set(doxygen_tagfiles "${tagfile}=http://en.cppreference.com/w/")
|
|
|
|
add_custom_command(
|
|
OUTPUT "${doxygen_index_file}"
|
|
COMMAND
|
|
"${CMAKE_COMMAND}" -E env
|
|
"DOXYGEN_OUTPUT_DIRECTORY=${doxygen_output_directory}"
|
|
"DOXYGEN_INCLUDE_PATH=${doxygen_include_path}"
|
|
"DOXYGEN_TAGFILES=${doxygen_tagfiles}"
|
|
"DOXYGEN_PLANTUML_JAR_PATH=${doxygen_plantuml_jar_path}"
|
|
"DOXYGEN_DOT_PATH=${doxygen_dot_path}" "${DOXYGEN_EXECUTABLE}"
|
|
"${doxyfile}"
|
|
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
|
DEPENDS "${dependencies}" "${tagfile}"
|
|
)
|
|
add_custom_target(
|
|
docs
|
|
DEPENDS "${doxygen_index_file}"
|
|
SOURCES "${dependencies}"
|
|
)
|