diff --git a/.gitignore b/.gitignore
index 8de6f0d719..118b21487c 100644
--- a/.gitignore
+++ b/.gitignore
@@ -14,6 +14,28 @@
 *.so.?.?.?
 *.a
 *.dylib
+lib/*
+
+# CMake
+*.cmake
+*.dir
+CMakeFiles
+INSTALL.*
+ZERO_CHECK.*
+CMakeCache.txt
+install_manifest.txt
+
+# Windows/Visual Studio
+*.vcproj*
+*.sln
+*.suo
+*.ncb
+*/Debug/*
+*/*/Debug/*
+*/Release/*
+*/*/Release/*
+*/RelWithDebInfo/*
+*/*/RelWithDebInfo/*
 
 objs_shared/
 objs_static/
diff --git a/CMakeLists.txt b/CMakeLists.txt
new file mode 100644
index 0000000000..70edccefb7
--- /dev/null
+++ b/CMakeLists.txt
@@ -0,0 +1,195 @@
+
+############ Setup project and cmake
+
+# Project name
+project (websocketpp)
+
+# Minimum cmake requirement. We should require a quite recent
+# cmake for the dependency find macros etc. to be up to date.
+cmake_minimum_required (VERSION 2.5)
+
+# Set CMake library search policy
+if (COMMAND cmake_policy)
+    cmake_policy (SET CMP0003 NEW)
+    cmake_policy (SET CMP0005 NEW)
+endif ()
+
+# Disable unnecessary build types
+set (CMAKE_CONFIGURATION_TYPES "Release;RelWithDebInfo;Debug" CACHE STRING "Configurations" FORCE)
+
+# Include our cmake macros
+set (CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
+include (CMakeHelpers)
+
+
+############  Build customization
+
+# Override from command line "CMake -D<OPTION>=TRUE/FALSE/0/1"
+option (ENABLE_CPP11 "Build websocketpp with CPP11 features enabled." TRUE)
+option (BUILD_EXAMPLES "Build websocketpp examples." TRUE)
+option (BUILD_TESTS "Build websocketpp tests." FALSE)
+
+
+############ Compiler specific setup
+
+set (WEBSOCKETPP_PLATFORM_LIBS "")
+set (WEBSOCKETPP_PLATFORM_TSL_LIBS "")
+set (WEBSOCKETPP_BOOST_LIBS "")
+
+# VC9 and C++11 reasoning
+if (ENABLE_CPP11 AND MSVC AND MSVC90)
+    message("* Detected Visual Studio 9 2008, disabling C++11 support.")
+    set (ENABLE_CPP11 FALSE)        
+endif ()
+
+# Detect clang. Not officially reported by cmake.
+if ("${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}" MATCHES ".*clang")
+    set (CMAKE_COMPILER_IS_CLANGXX 1)
+endif ()
+
+# C++11 defines
+if (ENABLE_CPP11)
+    add_definitions (-D_WEBSOCKETPP_CPP11_STL_)
+endif ()
+
+# Visual studio
+if (MSVC)
+    set (WEBSOCKETPP_BOOST_LIBS system thread regex)
+    set (CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /GL /Gy /GF /Ox /Ob2 /Ot /Oi /MP /arch:SSE2 /fp:fast")
+    set (CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /LTCG /INCREMENTAL:NO /OPT:REF /OPT:ICF")
+    add_definitions (/W3 /wd4996 /wd4995 /wd4355)
+    add_definitions (-DUNICODE -D_UNICODE)
+    add_definitions (-D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS)
+    add_definitions (-DNOMINMAX)
+endif ()
+
+# g++
+if (CMAKE_COMPILER_IS_GNUCXX)
+    set (WEBSOCKETPP_PLATFORM_LIBS pthread rt)
+    set (WEBSOCKETPP_PLATFORM_TSL_LIBS ssl crypto)
+    set (WEBSOCKETPP_BOOST_LIBS system thread)
+    set (CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} "-std=c++0x")
+    if (NOT APPLE)
+        add_definitions (-DNDEBUG -Wall -Wcast-align) # todo: should we use CMAKE_C_FLAGS for these?
+    endif ()
+
+    # Try to detect version. Note: Not tested!
+    execute_process (COMMAND ${CMAKE_CXX_COMPILER} "-dumpversion" OUTPUT_VARIABLE GCC_VERSION)
+    if ("${GCC_VERSION}" STRGREATER "4.4.0")
+        message("* C++11 support partially enabled due to GCC version ${GCC_VERSION}")
+        set (WEBSOCKETPP_BOOST_LIBS system thread regex)
+        add_definitions (-D_WEBSOCKETPP_NO_CPP11_REGEX_)
+    endif ()
+endif ()
+
+# clang
+if (CMAKE_COMPILER_IS_CLANGXX)
+    set (WEBSOCKETPP_PLATFORM_LIBS pthread rt)
+    set (WEBSOCKETPP_PLATFORM_TSL_LIBS ssl crypto)
+    set (CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} "-std=c++0x -stdlib=libc++") # todo: is libc++ really needed here?
+    if (NOT APPLE)
+        add_definitions (-DNDEBUG -Wall -Wno-padded) # todo: should we use CMAKE_C_FLAGS for these?
+    endif ()
+endif ()
+
+# OSX, can override above.
+if (APPLE)
+    add_definitions (-DNDEBUG -Wall -O0)
+endif ()
+
+
+############ Paths
+
+set (WEBSOCKETPP_ROOT ${CMAKE_CURRENT_SOURCE_DIR})
+set (WEBSOCKETPP_BIN ${WEBSOCKETPP_ROOT}/bin)
+set (WEBSOCKETPP_LIB ${WEBSOCKETPP_ROOT}/lib)
+set (WEBSOCKETPP_INCLUDE ${WEBSOCKETPP_ROOT}/websocketpp)
+set (WEBSOCKETPP_PREFIX ${WEBSOCKETPP_ROOT}/build)
+
+# CMake install step prefix. I assume linux users want the prefix to 
+# be the default /usr or /usr/local so this is only adjusted on Windows.
+# - Windows: Build the INSTALL project in your solution file.
+# - Linux/OSX: make install.
+if (MSVC)
+	set (CMAKE_INSTALL_PREFIX ${WEBSOCKETPP_PREFIX})
+endif ()
+
+
+############ Dependencies
+
+# Set BOOST_ROOT env variable or pass with cmake -DBOOST_ROOT=path.
+# BOOST_ROOT can also be defined by a previous run from cmake cache.
+if (NOT "$ENV{BOOST_ROOT_CPP11}" STREQUAL "")
+    # Scons documentation for BOOST_ROOT_CPP11:
+    # "look for optional second boostroot compiled with clang's libc++ STL library
+    # this prevents warnings/errors when linking code built with two different
+    # incompatible STL libraries."
+    file (TO_CMAKE_PATH "$ENV{BOOST_ROOT_CPP11}" BOOST_ROOT)
+    set (BOOST_ROOT ${BOOST_ROOT} CACHE PATH "BOOST_ROOT dependency path" FORCE)
+endif ()
+if ("${BOOST_ROOT}" STREQUAL "")
+    file (TO_CMAKE_PATH "$ENV{BOOST_ROOT}" BOOST_ROOT)
+    # Cache BOOST_ROOT for runs that do not define $ENV{BOOST_ROOT}.
+    set (BOOST_ROOT ${BOOST_ROOT} CACHE PATH "BOOST_ROOT dependency path" FORCE)
+endif ()
+
+message ("* Configuring Boost")
+message (STATUS "-- Using BOOST_ROOT")
+message (STATUS "       " ${BOOST_ROOT})
+
+if (MSVC)
+    set (Boost_USE_MULTITHREADED TRUE)
+    set (Boost_USE_STATIC_LIBS TRUE)
+else ()
+    set (Boost_USE_MULTITHREADED FALSE)
+    set (Boost_USE_STATIC_LIBS FALSE)
+endif ()
+
+set (Boost_FIND_REQUIRED TRUE)
+set (Boost_FIND_QUIETLY TRUE)
+set (Boost_DEBUG FALSE)
+set (Boost_USE_MULTITHREADED TRUE)
+set (Boost_ADDITIONAL_VERSIONS "1.39.0" "1.40.0" "1.41.0" "1.42.0" "1.43.0" "1.44.0" "1.46.1") # todo: someone who knows better spesify these!
+
+find_package (Boost 1.39.0 COMPONENTS "${WEBSOCKETPP_BOOST_LIBS}")
+
+if (Boost_FOUND)
+    # Boost is a project wide global dependency.
+    include_directories (${Boost_INCLUDE_DIRS})
+    link_directories (${Boost_LIBRARY_DIRS})
+
+    # Pretty print status
+    message (STATUS "-- Include Directories")
+    foreach (include_dir ${Boost_INCLUDE_DIRS})
+        message (STATUS "       " ${include_dir})
+    endforeach ()
+    message (STATUS "-- Library Directories")
+    foreach (library_dir ${Boost_LIBRARY_DIRS})
+        message (STATUS "       " ${library_dir})
+    endforeach ()
+    message (STATUS "-- Libraries")
+    foreach (boost_lib ${Boost_LIBRARIES})
+        message (STATUS "       " ${boost_lib})
+    endforeach ()
+    message ("")
+else ()
+    message (FATAL_ERROR "Failed to find required dependency: boost")
+endif ()
+
+
+############ Add projects
+
+# Add main library
+add_subdirectory (websocketpp)
+
+# Add examples
+if (BUILD_EXAMPLES)
+    add_subdirectory (examples)
+endif ()
+
+# Add tests
+if (BUILD_TESTS)
+    add_subdirectory (test)
+endif ()
+
+print_used_build_config()
diff --git a/cmake/CMakeHelpers.cmake b/cmake/CMakeHelpers.cmake
new file mode 100644
index 0000000000..d3ed20d0d5
--- /dev/null
+++ b/cmake/CMakeHelpers.cmake
@@ -0,0 +1,130 @@
+
+# Print build configuration
+macro (print_used_build_config)
+    message ("\n=========== Used Build Configuration =============\n")
+    message (STATUS "ENABLE_CPP11        = " ${ENABLE_CPP11})
+    message (STATUS "BUILD_EXAMPLES      = " ${BUILD_EXAMPLES})
+    message (STATUS "BUILD_TESTS         = " ${BUILD_TESTS})
+    message ("")
+    message (STATUS "WEBSOCKETPP_ROOT    = " ${WEBSOCKETPP_ROOT})
+    message (STATUS "WEBSOCKETPP_BIN     = " ${WEBSOCKETPP_BIN})
+    message (STATUS "WEBSOCKETPP_LIB     = " ${WEBSOCKETPP_LIB})
+    message (STATUS "Install prefix      = " ${CMAKE_INSTALL_PREFIX})
+    message ("")
+    message (STATUS "WEBSOCKETPP_BOOST_LIBS        = ${WEBSOCKETPP_BOOST_LIBS}")
+    message (STATUS "WEBSOCKETPP_PLATFORM_LIBS     = ${WEBSOCKETPP_PLATFORM_LIBS}")
+    message (STATUS "WEBSOCKETPP_PLATFORM_TSL_LIBS = ${WEBSOCKETPP_PLATFORM_TSL_LIBS}")
+    message ("") 
+endmacro ()
+
+# Lists all subdirectories to the RESULT variable.
+macro (list_subdirectories RESULT curdir)
+    set (_TEMP_DIRLIST "")
+    file (GLOB children RELATIVE ${curdir} ${curdir}/*)
+    foreach (child ${children})
+        if (IS_DIRECTORY ${curdir}/${child})
+            set (_TEMP_DIRLIST ${_TEMP_DIRLIST} ${child})
+        endif ()
+    endforeach ()
+    set (${RESULT} ${_TEMP_DIRLIST})
+endmacro ()
+
+# Adds the given folder_name into the source files of the current project. 
+# Use this macro when your module contains .cpp and .h files in several subdirectories.
+# Your sources variable needs to be SOURCE_FILES and headers variable HEADER_FILES.
+macro(add_source_folder folder_name)
+    file(GLOB H_FILES_IN_FOLDER_${folder_name} ${folder_name}/*.hpp ${folder_name}/*.h)
+    file(GLOB CPP_FILES_IN_FOLDER_${folder_name} ${folder_name}/*.cpp ${folder_name}/*.c)
+    source_group("Header Files\\${folder_name}" FILES ${H_FILES_IN_FOLDER_${folder_name}})
+    source_group("Source Files\\${folder_name}" FILES ${CPP_FILES_IN_FOLDER_${folder_name}})
+    set(HEADER_FILES ${HEADER_FILES} ${H_FILES_IN_FOLDER_${folder_name}})
+    set(SOURCE_FILES ${SOURCE_FILES} ${CPP_FILES_IN_FOLDER_${folder_name}})
+endmacro()
+
+# Initialize target.
+macro (init_target NAME)
+    set (TARGET_NAME ${NAME})
+    message ("** " ${TARGET_NAME})
+    
+    # Include our own module path. This makes #include "x.h" 
+    # work in project subfolders to include the main directory headers.
+    include_directories (${CMAKE_CURRENT_SOURCE_DIR})
+endmacro ()
+
+# Build library for static and shared libraries
+macro (build_library TARGET_NAME LIB_TYPE)
+    set (TARGET_LIB_TYPE ${LIB_TYPE})
+    message (STATUS "-- Build Type:")
+    message (STATUS "       " ${TARGET_LIB_TYPE} " library")
+   
+    add_library (${TARGET_NAME} ${TARGET_LIB_TYPE} ${ARGN})
+
+    target_link_libraries (${TARGET_NAME} ${WEBSOCKETPP_PLATFORM_LIBS})
+
+    if (MSVC)
+        if (${TARGET_LIB_TYPE} STREQUAL "SHARED")
+            set_target_properties (${TARGET_NAME} PROPERTIES LINK_FLAGS_RELEASE ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
+        else ()
+            set_target_properties (${TARGET_NAME} PROPERTIES STATIC_LIBRARY_FLAGS_RELEASE "/LTCG")
+        endif ()
+    endif ()
+
+    if (${TARGET_LIB_TYPE} STREQUAL "STATIC")
+        message (STATUS "-- Build Destination:")
+        message (STATUS "       " ${WEBSOCKETPP_LIB})
+        set_target_properties (${TARGET_NAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${WEBSOCKETPP_LIB})
+    endif ()
+
+    set_target_properties (${TARGET_NAME} PROPERTIES DEBUG_POSTFIX d)
+endmacro ()
+
+# Build executable for executables
+macro (build_executable TARGET_NAME)
+    set (TARGET_LIB_TYPE "EXECUTABLE")
+    message (STATUS "-- Build Type:")
+    message (STATUS "       " ${TARGET_LIB_TYPE})
+
+    add_executable (${TARGET_NAME} ${ARGN})
+
+    include_directories (${WEBSOCKETPP_ROOT} ${WEBSOCKETPP_INCLUDE})
+
+    set_target_properties (${TARGET_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${WEBSOCKETPP_BIN})
+    set_target_properties (${TARGET_NAME} PROPERTIES DEBUG_POSTFIX d)
+endmacro ()
+
+# Finalize target for all types
+macro (final_target)
+    if (${TARGET_LIB_TYPE} STREQUAL "SHARED")
+        install (TARGETS ${TARGET_NAME} 
+                 LIBRARY DESTINATION "bin" # non DLL platforms shared libs are LIBRARY
+                 RUNTIME DESTINATION "bin" # DLL platforms shared libs are RUNTIME
+                 ARCHIVE DESTINATION "lib" # DLL platforms static link part of the shared lib are ARCHIVE
+                 CONFIGURATIONS ${CMAKE_CONFIGURATION_TYPES})
+    endif ()
+    if (${TARGET_LIB_TYPE} STREQUAL "STATIC")
+        install (TARGETS ${TARGET_NAME} 
+                 ARCHIVE DESTINATION "lib" 
+                 CONFIGURATIONS ${CMAKE_CONFIGURATION_TYPES})
+    endif ()
+    if (${TARGET_LIB_TYPE} STREQUAL "EXECUTABLE")
+        install (TARGETS ${TARGET_NAME} 
+                 RUNTIME DESTINATION "bin" 
+                 CONFIGURATIONS ${CMAKE_CONFIGURATION_TYPES})
+    endif ()
+    
+    # install headers, directly from current source dir and look for subfolders with headers
+    file (GLOB TARGET_INSTALL_HEADERS *.hpp)
+    install (FILES ${TARGET_INSTALL_HEADERS} DESTINATION "include/${TARGET_NAME}")
+    list_subdirectories(SUBDIRS ${CMAKE_CURRENT_SOURCE_DIR})
+    foreach (SUBDIR ${SUBDIRS})
+        file (GLOB TARGET_INSTALL_HEADERS_SUBDIR ${SUBDIR}/*.hpp)
+        install (FILES ${TARGET_INSTALL_HEADERS_SUBDIR} DESTINATION "include/${TARGET_NAME}/${SUBDIR}")
+    endforeach ()
+
+    # Pretty printing
+    message ("")
+endmacro ()
+
+macro (link_boost)
+    target_link_libraries (${TARGET_NAME} ${Boost_LIBRARIES})
+endmacro ()
\ No newline at end of file
diff --git a/examples/CMakeLists.txt b/examples/CMakeLists.txt
new file mode 100644
index 0000000000..5dd4873a67
--- /dev/null
+++ b/examples/CMakeLists.txt
@@ -0,0 +1,8 @@
+
+# Roams all subdirs for CMakeLists.txt
+list_subdirectories(SUBDIRS ${CMAKE_CURRENT_SOURCE_DIR})
+foreach (SUBDIR ${SUBDIRS})
+    if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${SUBDIR}/CMakeLists.txt")
+        add_subdirectory (${SUBDIR})
+    endif ()
+endforeach ()
diff --git a/examples/echo_client/CMakeLists.txt b/examples/echo_client/CMakeLists.txt
new file mode 100644
index 0000000000..a3d6d3b2e5
--- /dev/null
+++ b/examples/echo_client/CMakeLists.txt
@@ -0,0 +1,11 @@
+    
+file (GLOB SOURCE_FILES *.cpp)
+file (GLOB HEADER_FILES *.hpp)
+
+init_target (echo_client)
+
+build_executable (${TARGET_NAME} ${SOURCE_FILES} ${HEADER_FILES})
+
+link_boost ()
+final_target ()
+
diff --git a/examples/echo_server/CMakeLists.txt b/examples/echo_server/CMakeLists.txt
new file mode 100644
index 0000000000..adacc6aa76
--- /dev/null
+++ b/examples/echo_server/CMakeLists.txt
@@ -0,0 +1,10 @@
+    
+file (GLOB SOURCE_FILES *.cpp)
+file (GLOB HEADER_FILES *.hpp)
+
+init_target (echo_server)
+
+build_executable (${TARGET_NAME} ${SOURCE_FILES} ${HEADER_FILES})
+
+link_boost ()
+final_target ()
diff --git a/websocketpp/CMakeLists.txt b/websocketpp/CMakeLists.txt
new file mode 100644
index 0000000000..908ed73b6a
--- /dev/null
+++ b/websocketpp/CMakeLists.txt
@@ -0,0 +1,19 @@
+
+init_target (libwebsocketpp)
+
+# Sources from root dir
+file (GLOB SOURCE_FILES *.cpp)
+file (GLOB HEADER_FILES *.hpp)
+
+# Sources from subdirectories.
+list_subdirectories (SUBDIRS ${CMAKE_CURRENT_SOURCE_DIR})
+foreach (SUBDIR ${SUBDIRS})
+    # Filter out certain subdirs from 3rd party code
+    if (NOT ${SUBDIR} STREQUAL "sha1" AND NOT ${SUBDIR} STREQUAL "md5") # todo: AND NOT ${SUBDIR} STREQUAL "base64"
+        add_source_folder (${SUBDIR})
+    endif ()
+endforeach ()
+
+build_library (${TARGET_NAME} STATIC ${SOURCE_FILES} ${HEADER_FILES})
+
+final_target ()
\ No newline at end of file
diff --git a/websocketpp/endpoint.hpp b/websocketpp/endpoint.hpp
index 2c59a3f614..902ae4409c 100644
--- a/websocketpp/endpoint.hpp
+++ b/websocketpp/endpoint.hpp
@@ -306,6 +306,7 @@ public:
     connection_ptr get_con_from_hdl(connection_hdl hdl, lib::error_code & ec) {
         scoped_lock_type lock(m_mutex);
         connection_ptr con = lib::static_pointer_cast<connection_type>(
+#endif
             hdl.lock());
         if (!con) {
             ec = error::make_error_code(error::bad_connection);