CMake Refactor and Github Actions Hook

2025-12-06 17:27:58 +00:00 · 2022-01-05 07:36:56 -08:00
parent aa65d1669d
commit 2f0b3235ee
11 changed files with 105 additions and 104 deletions
--- a/CMake/deps/Boost.cmake
+++ b/CMake/deps/Boost.cmake
@@ -0,0 +1,6 @@
+set(Boost_USE_STATIC_LIBS ON)
+set(Boost_USE_STATIC_RUNTIME ON)
+
+find_package(Boost 1.75 COMPONENTS filesystem log_setup log thread system REQUIRED)
+
+target_link_libraries(clio PUBLIC ${Boost_LIBRARIES})
--- a/CMake/deps/Postgres.cmake
+++ b/CMake/deps/Postgres.cmake
@@ -0,0 +1,46 @@
+find_package(PostgreSQL)
+
+if(NOT PostgreSQL_FOUND)
+        message("find_package did not find postgres")
+        find_library(postgres NAMES pq libpq libpq-dev pq-dev postgresql-devel)
+        find_path(libpq-fe NAMES libpq-fe.h PATH_SUFFIXES postgresql pgsql include)
+    if(NOT libpq-fe_FOUND OR NOT postgres_FOUND)
+        message("No system installed Postgres found. Will build")
+        add_library(postgres SHARED IMPORTED GLOBAL)
+        ExternalProject_Add(postgres_src
+            PREFIX ${nih_cache_path}
+            GIT_REPOSITORY https://github.com/postgres/postgres.git
+            GIT_TAG master
+            CONFIGURE_COMMAND ./configure --without-readline
+            BUILD_COMMAND ${CMAKE_COMMAND} -E env --unset=MAKELEVEL make
+            UPDATE_COMMAND ""
+            BUILD_IN_SOURCE 1
+            INSTALL_COMMAND ""
+            BUILD_BYPRODUCTS <BINARY_DIR>/src/interfaces/libpq/${CMAKE_SHARED_LIBRARY_PREFIX}pq.so
+            )
+        ExternalProject_Get_Property (postgres_src SOURCE_DIR)
+        ExternalProject_Get_Property (postgres_src BINARY_DIR)
+        set (postgres_src_SOURCE_DIR "${SOURCE_DIR}")
+        file (MAKE_DIRECTORY ${postgres_src_SOURCE_DIR}/src/include)
+        file (MAKE_DIRECTORY ${postgres_src_SOURCE_DIR}/src/interfaces/libpq)
+        list(APPEND INCLUDE_DIRS ${SOURCE_DIR}/src/include)
+        list(APPEND INCLUDE_DIRS ${SOURCE_DIR}/src/interfaces/libpq)
+        set_target_properties (postgres PROPERTIES
+            IMPORTED_LOCATION
+            ${BINARY_DIR}/src/interfaces/libpq/${CMAKE_SHARED_LIBRARY_PREFIX}pq.so
+            INTERFACE_INCLUDE_DIRECTORIES
+            "${INCLUDE_DIRS}")
+        add_dependencies(postgres postgres_src)
+        file(TO_CMAKE_PATH "${postgres_src_SOURCE_DIR}" postgres_src_SOURCE_DIR)
+    target_link_libraries(clio PUBLIC postgres)
+    else()
+        message("Found system installed Postgres via find_libary")
+        target_include_directories(clio INTERFACE ${libpq-fe})
+        target_link_libraries(clio INTERFACE ${postgres})
+    endif()
+else()
+    message("Found system installed Postgres via find_package")
+    message("${PostgreSQL_INCLUDE_DIRS}")
+    include_directories(clio INTERFACE "${PostgreSQL_INCLUDE_DIRS}")
+    target_link_libraries(clio PUBLIC ${PostgreSQL_LIBRARIES})
+endif()
--- a/CMake/deps/cassandra.cmake
+++ b/CMake/deps/cassandra.cmake
@@ -0,0 +1,151 @@
+find_package(ZLIB REQUIRED)
+
+find_library(cassandra NAMES cassandra)
+if(NOT cassandra)
+    message("System installed Cassandra cpp driver not found. Will build")
+    find_library(zlib NAMES zlib1g-dev zlib-devel zlib z)
+    if(NOT zlib)
+        message("zlib not found. will build")
+        add_library(zlib STATIC IMPORTED GLOBAL)
+        ExternalProject_Add(zlib_src
+            PREFIX ${nih_cache_path}
+            GIT_REPOSITORY https://github.com/madler/zlib.git
+            GIT_TAG master
+            INSTALL_COMMAND ""
+            BUILD_BYPRODUCTS <BINARY_DIR>/${CMAKE_STATIC_LIBRARY_PREFIX}z.a
+            )
+        ExternalProject_Get_Property (zlib_src SOURCE_DIR)
+        ExternalProject_Get_Property (zlib_src BINARY_DIR)
+        set (zlib_src_SOURCE_DIR "${SOURCE_DIR}")
+        file (MAKE_DIRECTORY ${zlib_src_SOURCE_DIR}/include)
+        set_target_properties (zlib PROPERTIES
+            IMPORTED_LOCATION
+            ${BINARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}z.a
+            INTERFACE_INCLUDE_DIRECTORIES
+            ${SOURCE_DIR}/include)
+        add_dependencies(zlib zlib_src)
+        file(TO_CMAKE_PATH "${zlib_src_SOURCE_DIR}" zlib_src_SOURCE_DIR)
+    endif()
+    find_library(krb5 NAMES krb5-dev libkrb5-dev)
+    if(NOT krb5)
+        message("krb5 not found. will build")
+        add_library(krb5 STATIC IMPORTED GLOBAL)
+        ExternalProject_Add(krb5_src
+            PREFIX ${nih_cache_path}
+            GIT_REPOSITORY https://github.com/krb5/krb5.git
+            GIT_TAG master
+            UPDATE_COMMAND ""
+            CONFIGURE_COMMAND autoreconf src && CFLAGS=-fcommon ./src/configure --enable-static --disable-shared
+            BUILD_IN_SOURCE 1
+            BUILD_COMMAND make
+            INSTALL_COMMAND ""
+            BUILD_BYPRODUCTS <SOURCE_DIR>/lib/${CMAKE_STATIC_LIBRARY_PREFIX}krb5.a
+            )
+        message(${ep_lib_prefix}/krb5.a)
+        message(${CMAKE_STATIC_LIBRARY_PREFIX}krb5.a)
+        ExternalProject_Get_Property (krb5_src SOURCE_DIR)
+        ExternalProject_Get_Property (krb5_src BINARY_DIR)
+        set (krb5_src_SOURCE_DIR "${SOURCE_DIR}")
+        file (MAKE_DIRECTORY ${krb5_src_SOURCE_DIR}/include)
+        set_target_properties (krb5 PROPERTIES
+            IMPORTED_LOCATION
+	    ${SOURCE_DIR}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}krb5.a
+            INTERFACE_INCLUDE_DIRECTORIES
+            ${SOURCE_DIR}/include)
+        add_dependencies(krb5 krb5_src)
+        file(TO_CMAKE_PATH "${krb5_src_SOURCE_DIR}" krb5_src_SOURCE_DIR)
+    endif()
+
+
+    find_library(libuv1 NAMES uv1 libuv1 liubuv1-dev libuv1:amd64)
+
+
+    if(NOT libuv1)
+        message("libuv1 not found, will build")
+        add_library(libuv1 STATIC IMPORTED GLOBAL)
+        ExternalProject_Add(libuv_src
+            PREFIX ${nih_cache_path}
+            GIT_REPOSITORY https://github.com/libuv/libuv.git
+            GIT_TAG v1.x
+            INSTALL_COMMAND ""
+            BUILD_BYPRODUCTS <BINARY_DIR>/${CMAKE_STATIC_LIBRARY_PREFIX}uv_a.a
+            )
+
+        ExternalProject_Get_Property (libuv_src SOURCE_DIR)
+        ExternalProject_Get_Property (libuv_src BINARY_DIR)
+        set (libuv_src_SOURCE_DIR "${SOURCE_DIR}")
+        file (MAKE_DIRECTORY ${libuv_src_SOURCE_DIR}/include)
+
+        set_target_properties (libuv1 PROPERTIES
+            IMPORTED_LOCATION
+            ${BINARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}uv_a.a
+            INTERFACE_INCLUDE_DIRECTORIES
+            ${SOURCE_DIR}/include)
+        add_dependencies(libuv1 libuv_src)
+
+        file(TO_CMAKE_PATH "${libuv_src_SOURCE_DIR}" libuv_src_SOURCE_DIR)
+    endif()
+    add_library (cassandra STATIC IMPORTED GLOBAL)
+    ExternalProject_Add(cassandra_src
+        PREFIX ${nih_cache_path}
+        GIT_REPOSITORY https://github.com/datastax/cpp-driver.git
+        GIT_TAG master
+        CMAKE_ARGS
+        -DLIBUV_ROOT_DIR=${BINARY_DIR}
+        -DLIBUV_INCLUDE_DIR=${SOURCE_DIR}/include
+        -DCASS_BUILD_STATIC=ON
+        -DCASS_BUILD_SHARED=OFF
+        INSTALL_COMMAND ""
+        BUILD_BYPRODUCTS <BINARY_DIR>/${CMAKE_STATIC_LIBRARY_PREFIX}cassandra_static.a
+        )
+
+    ExternalProject_Get_Property (cassandra_src SOURCE_DIR)
+    ExternalProject_Get_Property (cassandra_src BINARY_DIR)
+    set (cassandra_src_SOURCE_DIR "${SOURCE_DIR}")
+    file (MAKE_DIRECTORY ${cassandra_src_SOURCE_DIR}/include)
+
+    set_target_properties (cassandra PROPERTIES
+        IMPORTED_LOCATION
+        ${BINARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}cassandra_static.a
+        INTERFACE_INCLUDE_DIRECTORIES
+        ${SOURCE_DIR}/include)
+    message("cass dirs")
+    message(${BINARY_DIR})
+    message(${SOURCE_DIR})
+    message(${BINARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}cassandra_static.a)
+    add_dependencies(cassandra cassandra_src)
+
+    if(NOT libuv1)
+        ExternalProject_Add_StepDependencies(cassandra_src build libuv1)
+        target_link_libraries(cassandra INTERFACE libuv1)
+    else()
+        target_link_libraries(cassandra INTERFACE ${libuv1})
+    endif()
+    if(NOT krb5)
+
+        ExternalProject_Add_StepDependencies(cassandra_src build krb5)
+        target_link_libraries(cassandra INTERFACE krb5)
+    else()
+        target_link_libraries(cassandra INTERFACE ${krb5})
+    endif()
+
+    if(NOT zlib)
+        ExternalProject_Add_StepDependencies(cassandra_src build zlib)
+        target_link_libraries(cassandra INTERFACE zlib)
+    else()
+        target_link_libraries(cassandra INTERFACE ${zlib})
+    endif()
+	set(OPENSSL_USE_STATIC_LIBS TRUE)
+	find_package(OpenSSL REQUIRED)
+	target_link_libraries(cassandra INTERFACE OpenSSL::SSL)
+
+    file(TO_CMAKE_PATH "${cassandra_src_SOURCE_DIR}" cassandra_src_SOURCE_DIR)
+    target_link_libraries(clio PUBLIC cassandra)
+else()
+    message("Found system installed cassandra cpp driver")
+    message(${cassandra})
+
+    find_path(cassandra_includes NAMES cassandra.h REQUIRED)
+    target_link_libraries (clio PUBLIC ${cassandra})
+    target_include_directories(clio INTERFACE ${cassandra_includes})
+endif()
--- a/CMake/deps/gtest.cmake
+++ b/CMake/deps/gtest.cmake
@@ -0,0 +1,17 @@
+FetchContent_Declare(
+  googletest
+  URL https://github.com/google/googletest/archive/609281088cfefc76f9d0ce82e1ff6c30cc3591e5.zip
+)
+
+FetchContent_GetProperties(googletest)
+
+if(NOT googletest_POPULATED)
+  FetchContent_Populate(googletest)
+  add_subdirectory(${googletest_SOURCE_DIR} ${googletest_BINARY_DIR} EXCLUDE_FROM_ALL)
+endif()
+
+target_link_libraries(clio_tests PUBLIC clio gtest_main)
+
+enable_testing()
+
+include(GoogleTest)
--- a/CMake/deps/rippled.cmake
+++ b/CMake/deps/rippled.cmake
@@ -0,0 +1,15 @@
+set(NIH_CACHE_ROOT "${CMAKE_CURRENT_BINARY_DIR}" CACHE INTERNAL "")
+FetchContent_Declare(rippled
+  GIT_REPOSITORY https://github.com/cjcobb23/rippled.git
+  GIT_TAG clio
+  GIT_SHALLOW ON
+)
+
+FetchContent_GetProperties(rippled)
+if(NOT rippled_POPULATED)
+  FetchContent_Populate(rippled)
+  add_subdirectory(${rippled_SOURCE_DIR} ${rippled_BINARY_DIR} EXCLUDE_FROM_ALL)
+endif()
+
+target_link_libraries(clio PUBLIC xrpl_core grpc_pbufs)
+target_include_directories(clio PUBLIC ${rippled_SOURCE_DIR}/src ) # TODO: Seems like this shouldn't be needed?
--- a/CMake/install/PostInstall.cmake
+++ b/CMake/install/PostInstall.cmake
@@ -0,0 +1,4 @@
+execute_process(
+  COMMAND ln -s ${CMAKE_INSTALL_PREFIX}/${CLIO_INSTALL_DIR}/bin/clio_server /usr/local/bin/clio_server
+  COMMAND_ECHO STDOUT
+  )
--- a/CMake/install/install.cmake
+++ b/CMake/install/install.cmake
@@ -0,0 +1,7 @@
+set(CLIO_INSTALL_DIR /opt/clio)
+set(CMAKE_INSTALL_PREFIX ${CLIO_INSTALL_DIR})
+
+install(TARGETS clio_server DESTINATION bin)
+# install(TARGETS clio_tests DESTINATION bin) # NOTE: Do we want to install the tests?
+install(FILES example-config.json DESTINATION etc/clio)
+install(SCRIPT "${CMAKE_SOURCE_DIR}/CMake/install/PostInstall.cmake")
--- a/CMake/settings.cmake
+++ b/CMake/settings.cmake
@@ -0,0 +1,5 @@
+set(CMAKE_CXX_EXTENSIONS OFF)
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-narrowing")
--- a/CMake/version-config.h
+++ b/CMake/version-config.h
@@ -0,0 +1 @@
+#define VERSION "@PROJECT_VERSION@"